Wifi Reconnect - nicht blockierend

[Arduino4Fun]

Hallo,

ich möchte in einer Anwendung die Tasteneingaben, Anzeigen in Verbindung mit WLAN+MQTT die Fehlerbehandlung so lösen, dass ein Reconnect des WLAN-Netzwerk bzw. der MQTT Verbindung den Rest der Apllikation nicht beeinträchtigt z.B. Tasteneingaben etc. funktionieren weiterhin, daher keine (blockierende) Schleifen und keine delay() und möglichst kein ESP.restart().

Nun zur Frage. Welche Anweisungen sind für ein WLAN Reconnect mindestens aufzurufen um das Netzwerk erneut zu starten?

Zur Einrichtung des Netzwerk mit statischer IP reicht ja

Code:

WiFi.mode( WIFI_STA );
  WiFi.persistent( false );
  WiFi.config( ip,gateway,subnet );
  WiFi.begin( ssid,password );

und wie ich gelernt habe

Code:

WiFi.persistent( false );

damit die Settings nicht im Flash abgelegt werden

Weitere Frage. Wie testet ihr die "Nicht Funktion" sprich WLAN Unterbrechung ohne den häuslichen Frieden zu stören. Fehler per Tastendruck injizieren - welche sinnvolle Anweisung?

Gruß Arduino4Fun

[Tommy56]

(28.11.2020 18:59)Arduino4Fun schrieb:  Weitere Frage. Wie testet ihr die "Nicht Funktion" sprich WLAN Unterbrechung ohne den häuslichen Frieden zu stören. Fehler per Tastendruck injizieren - welche sinnvolle Anweisung?

Wenn Du ein Nichtvorhandensein des WLAN testen willst, dann musst Du entweder das WLAN abschalten oder einen Faradayschen Käfig drumrum bauen. Aufpassen, die USB-Strippe kan den Käfig löchrig machen

Du kannst den Status Deiner WLAN-Verbindung abfragen.

Um welchen Prozessor geht es? Meine ESP8266 haben sich immer selbst reconnected.

Gruß Tommy

[Arduino4Fun]

Hallo Tommy,

meine Idee ist eine andere. Per Taste die ich über ESP einlese, manipuliere ich die ESP SW (z.b. falsche SSID) und dieser läuft dann die Routinen für die Fehlerbehandlung durch, danach weiterer Tastendruck, sprich toggeln richtige SSID, dann muss der ESP wieder einsteigen.

Fehlerstimmulierung in Anwendung, nicht von Aussen durch z.B. Abschaltung des Netzwerk

Ziel HW ist 8266 und ESP32

Gruß Arduino4Fun

[Tommy56]

Die geänderte SSID wird ihn aber nicht weiter interessieren, wenn er ins Netz eingeklinkt ist.
Auf alle Fälle solltest Du beim ESP8266 gleich am Anfang vom Setup schreiben

Code:

WiFi.persistent(false);

Ob es das beim ESP32 gibt, musst Du schauen.
Wenn Du ohne diese Zeile schon mal connected warst, musst Du die WiFi-Settings beim Hochladen mit löschen.

Ob Deine Idee funktioniert, musst Du experimentell ermitteln. Du kannst uns das Ergebnis gern mitteilen.

Gruß Tommy

[amithlon]

Hallo,

die Eventhandler benutzen:

Code:

...
WiFiEventHandler wifiConnectHandler;
WiFiEventHandler wifiDisconnectHandler;

void connectToWifi(void);
void onWifiConnect(const WiFiEventStationModeGotIP& event);
...

setup()
{
...
// Start WiFi
  wifiConfig();

  wifiConnectHandler = WiFi.onStationModeGotIP(onWifiConnect);
  connectToWifi();
...
}

// ###############################################################
// ---------------------- WiFi-Tools ------------------------------
// ###############################################################

void connectToWifi()
{
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid.c_str(), password.c_str());
}

//----------------------------------------------------------------------

void onWifiConnect(const WiFiEventStationModeGotIP& event)
{
#ifdef DEBUG
  Serial.println("Connected to Wi-Fi.");
  Serial.println(WiFi.localIP());
#endif

// Hier bei Bedarf noch MQTT connect einfügen.

}

//----------------------------------------------------------------------

void onWifiDisconnect(const WiFiEventStationModeDisconnected& event)
{
  wifiReconnectTimer.once(2, connectToWifi);
}

WiFi.persistent(false); habe ich nie gesetzt, das bleibt aktiv. Die ESP8266 laufen fast alle 24/7 und bisher ist kein Flash gestorben, so oft verbindet er sich ja da nicht neu.

Gruß aus Berlin
Michael

[Arduino4Fun]

Hallo Michael,

danke für die Antwort. Zwei Fragen

wie bindest du den "onWifiDisconnect" handler im setup() ein und was ist der Inhalt der Funktion "wifiReconnectTimer.once(2, connectToWifi);" bzw. wo deklariert

Danke und Gruß Arduino4Fun

[Arduino4Fun]

Hallo Michael,

Thema weitestgehend gelöst. Habe nun folgenden "Basis-Code".

Code:

#define   BTN1  D3

OneButton Btn1_Key( BTN1,true );

WiFiEventHandler wifiConnectHandler;
WiFiEventHandler wifiDisconnectHandler;

void WiFi_connect(void);
void onWifiConnect(const WiFiEventStationModeGotIP& event);
void onWifiDisconnect(const WiFiEventStationModeDisconnected& event);

//----------------------------------------------------------------------
void Btn1_Key_Proc()
{
  static bool WLAN_Off = true;

  if( WLAN_Off==true )
  {
    Serial.println( "Switch WLAN OFF" );
    WiFi.disconnect();
    WiFi.mode( WIFI_OFF );
    WiFi.forceSleepBegin();
    WLAN_Off = false;
  }
  else
  {
    WiFi_connect();
    Serial.println( "Switch WLAN ON" );
    WLAN_Off = true;
  }
}

//----------------------------------------------------------------------
void WiFi_connect()
{
  WiFi.mode( WIFI_STA );
  WiFi.persistent( false );
  WiFi.config( ip,gateway,subnet );
  WiFi.begin( ssid,password );
}

//----------------------------------------------------------------------
void onWifiConnect(const WiFiEventStationModeGotIP& event)
{
  Serial.print("Connected to WiFi: ");
  Serial.println( WiFi.localIP() );

  // Hier bei Bedarf noch MQTT connect einfügen.
}

//----------------------------------------------------------------------
void onWifiDisconnect(const WiFiEventStationModeDisconnected& event)
{
  // wifiReconnectTimer.once(2, connectToWifi);
  
  Serial.println("WiFi Disconneted");
}

//----------------------------------------------------------------------
void setup()
{
  Serial.begin(115200);

  Btn1_Key.attachClick( Btn1_Key_Proc );

  wifiConnectHandler = WiFi.onStationModeGotIP( onWifiConnect );
  wifiDisconnectHandler = WiFi.onStationModeDisconnected( onWifiDisconnect );  
  
  WiFi_connect();
}

//----------------------------------------------------------------------
void loop()
{
  Btn1_Key.tick();
}

Mit dem Taster des WeMos Button Shield kann ich bereits WLAN deaktivieren und wieder einschalten. Die Routinen des Handler werden erfolgreich angesprungen.
Jetzt muss ich mir noch eine Logik für die Behandlung des Disconnect überlegen und MQTT einbinden.

Danke und Gruß Arduino4Fun