Ultraschall mit einer 3,2 Zoll verbinden

[jgrothe]

Hallo Leute, ich habe da noch eine heraus Forderung. Kann ein vorhanden
UTFT_Geometry Radar auf 3,2 Zoll Display und ein fertigen Ultraschall Sketch
mit ein andere verbunden werden?
Das soll ein Haustür Radar werden, welches in der Nacht nicht erwünscht
Besucher abschrecken kann.

und wie wird der Sketch hier richtig eingestellt?

[rkuehle]

Klar, warum soll man nicht die Funktionen aus zwei Sketchen zusammenführen können. Dazu müsste man allerdings die Sketche sehen
Einfügen kannst du die Sketche mit Klick auf das # - Symbol zu Beginn und Ende des Codes.
Natürlich müsstest du schon noch sagen was am Ende der zusammengeführte Sketch machen soll.

Grüße Ricardo

[jgrothe]

Gelöscht:::

[rkuehle]

Öhm,
ich frage nochmal: was soll der Ergebnissketch machen.
Besser gesagt wie soll er wann reagieren?
- soll er die Entfernung laufend abbilden?
- soll er bei einer bestimmten Entfernung Alarm schlagen?
- wie soll der Alarm umgesetzt werden (optisch/akustisch)?
Ein bisschen was an konkreter Info fehlt halt noch
Grüße RK

[jgrothe]

(19.05.2015 19:42)rkuehle schrieb:  Öhm,
ich frage nochmal: was soll der Ergebnissketch machen.
Besser gesagt wie soll er wann reagieren?
- soll er die Entfernung laufend abbilden?
- soll er bei einer bestimmten Entfernung Alarm schlagen?
- wie soll der Alarm umgesetzt werden (optisch/akustisch)?
Ein bisschen was an konkreter Info fehlt halt noch
Grüße RK

Hallo Ricardo,
wenn es möglich ist sollte das Radar die Entfernung am untern Rand ausgeben,
// das Objekt wie näher kommt und ab 100cm den Alarm auf ein freien Pin
optisch ausgeben.

Danke Jörg

---

(19.05.2015 20:17)jgrothe schrieb:  

(19.05.2015 19:42)rkuehle schrieb:  Öhm,
ich frage nochmal: was soll der Ergebnissketch machen.
Besser gesagt wie soll er wann reagieren?
- soll er die Entfernung laufend abbilden?
- soll er bei einer bestimmten Entfernung Alarm schlagen?
- wie soll der Alarm umgesetzt werden (optisch/akustisch)?
Ein bisschen was an konkreter Info fehlt halt noch
Grüße RK

Hallo Ricardo,
wenn es möglich ist sollte das Radar die Entfernung am untern Rand ausgeben,
// das Objekt wie näher kommt und ab 100cm den Alarm auf ein freien Pin
optisch ausgeben.

Danke Jörg

Den Sketch von Radar kann die Display anzeige schon mal weck, macht ihn
ein stück schlanker!!!

[jgrothe]

Hallo Ricardo,
werde an den Sketsch weiter arbeiten, die beiden lasse ich stehen kann ja für andere brauch bar sein.

Danke für deine Hilfe Gruß Jörg

[rkuehle]

Hier jetzt der (hoffentlich) fertige Code:

Code:

#include <UTFT.h>
#include <UTFT_Geometry.h>
extern uint8_t SmallFont[];
UTFT myGLCD(ITDB32S, 38, 39, 40, 41);
UTFT_Geometry geo(&myGLCD);
// Konstanten
// Pins fuer USS
const unsigned int vccPin = 14; // VCC
const unsigned int pingPin = 15; // Ping
const unsigned int inPin = 16; // Trigger
const unsigned int gndPin = 17; // Ground
// Messintervall in ms
const unsigned int messintervall = 100;
// Alarmpin
const unsigned int alarmPin = 3;
const unsigned int alarmdistanz = 100; // in cm
// Variablen
// Stringvariable für Ausgabe Entfernung
String numberString = " ";
// Entfernungswert
unsigned long cm;
void setup()
{
  // Spannungsversorgung USS
  ADCSRA = 0; // ADC off
  ACSR = B10000000; // Komparator off
  DIDR0 = DIDR0 | B00111111; // Analog off
  pinMode(vccPin, OUTPUT);
  pinMode(gndPin, OUTPUT);
  digitalWrite(vccPin, LOW);
  digitalWrite(vccPin, HIGH);
  // delay damit sich der USS stabiliseren kann
  delay(2000);
  // Start LCD und Zeichnen oberes Banner
  myGLCD.InitLCD();
  myGLCD.clrScr();
  myGLCD.setFont(SmallFont);
  myGLCD.setBackColor(VGA_BLACK);
  myGLCD.setColor(VGA_RED);
  myGLCD.fillRect(0, 0, 319, 13);
  myGLCD.setColor(VGA_GRAY);
  myGLCD.fillRect(0, 226, 319, 239);
  myGLCD.setColor(VGA_WHITE);
  myGLCD.setBackColor(VGA_RED);
  myGLCD.print("Radar", CENTER, 1);
  // Zeichnen der Einteilung
  myGLCD.setColor(VGA_LIME);
  for (int i = -40; i <= 40; i += 8)
  {
    geo.drawArc(160, 240, 205, i, i, 10);
  }
  // Zeichnen blauer Rahmen
  myGLCD.setColor(VGA_BLUE);
  myGLCD.drawRect(0, 14, 319, 225);
}
void loop()
{
  // USS abfragen und Umwandeln der Rückgabe in String
  int i = ping();
  numberString = String((int) cm);
  // Ausgabe unteres Banner mit Entfernungsangabe
  myGLCD.setBackColor(VGA_GRAY);
  myGLCD.setColor(VGA_YELLOW);
  myGLCD.print("Entfernung " + numberString + " cm", CENTER, 227);
  // Zeiger für Entfernung setzen...
  myGLCD.setColor(VGA_YELLOW);
  geo.drawArc(160, 240, 110, i, i, 170);
  // ... und wieder ausblenden
  int l = i;
  myGLCD.setColor(VGA_BLACK);
  geo.drawArc(160, 240, 110, l, l, 170);
  // Verzögerung bis nächste Messung
  delay(messintervall);
}
// Funktion fragt USS ab und gibt Entfernung zurück
int ping()
{
  // Variablen für Dauer der ping,
  long duration ;
  // Der PING wird mit einem High-Impuls von 2 oder mehr Mikrosekunden ausgelöst.
  // Kurzer LOW Impuls vorher um einen sauberen HIGH-Impuls zu gewährleisten:
  pinMode(pingPin, OUTPUT);
  digitalWrite(pingPin, LOW);
  delayMicroseconds(2);
  digitalWrite(pingPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(pingPin, LOW);
  // Triggerpin auslesen und über Zeitdauer die Entfernung berechnen
  pinMode(inPin, INPUT);
  duration = pulseIn(inPin, HIGH);
  cm = microsecondsToCentimeters(duration);
  // Wenn Entfernung <= 1 m dann Alarm
  if (cm > alarmdistanz) digitalWrite(alarmPin, LOW); else digitalWrite(alarmPin, HIGH);
  // Rückgabe der auf die Einteilung gemappeten Entfernung
  return map((int) cm, 2, 400, -40, 40);
}
// Funktion rechnet Zeitdauer in Entfernung um
long microsecondsToCentimeters(long microseconds) {
  // Die Schallgeschwindigkeit beträgt 340 m / s oder 29 Mikrosekunden pro Zentimeter.
  return microseconds / 29 / 2;
}

Ich habe das Teil so geschrieben, dass der Sensor direkt über Digitalpins vom Arduino mit Strom versorgt wird
Grüße Ricardo
PS: Edit

[jgrothe]

Hallo Ricardo,
erst mal Hut ab super Leistung
nur habe ich beim Verifizieren ein Fehler erhalten



Arduino: 1.7.3 (Windows 7), Platine: "Arduino Mega und Mega 2560, ATmega2560 (Mega 2560)"

sketch_may21a.ino: 104: 1: Fehler: Streu '\' in Programm

sketch_may21a.ino: 104: 1: Fehler: 'Ich' bezeichnet keine Typ

Fehler beim kompilieren.

Of this Bericht hätte mehr Informationen mit
"Ausführliche Ausgabe während der Kompilierung"
aktiviert in Datei> einstellungen


liegt er bei mir????

Danke Jörg

---

Ricardo, Entschuldigung

Fehler lag bei mir konnte behoben werden, noch mal vielen dank für die Hilfe
ich glaube das der Sketsch mit mein jetzigen wissen lange nur ein Traum gewesen
wehre.
Bleib bitte wie Du bist ein netter und hilfsbereite

Danke das Du dir zeit für mich genommen hast