INFO: Dieses Forum nutzt Cookies...
Cookies sind für den Betrieb des Forums unverzichtbar. Mit der Nutzung des Forums erklärst Du dich damit einverstanden, dass wir Cookies verwenden.

Es wird in jedem Fall ein Cookie gesetzt um diesen Hinweis nicht mehr zu erhalten. Desweiteren setzen wir Google Adsense und Google Analytics ein.

Antwort schreiben 
 
Themabewertung:
  • 1 Bewertungen - 4 im Durchschnitt
  • 1
  • 2
  • 3
  • 4
  • 5
Problem am Mega mit pin 10
18.01.2020, 13:52 (Dieser Beitrag wurde zuletzt bearbeitet: 18.01.2020 15:39 von Franz54.)
Beitrag #1
Problem am Mega mit pin 10
Ich habe hier einen Code der als ProgrammCode absolut keine "Bedeutung" hat. Er ist zwar absolut lauffähig in allen enthaltenen Funktionen, aber ich habe das nur zusammengesetzt, um beim Erstellen eines neuen Programmes schneller zu sein.

Stelle einfach den neuen Prgrammcode den ich erstelle und den hier gezeigten Code nebeneinader auf den beiden Bildschirmen, und kopiere mir die Funktionen, die ich im neuen Code brauche rüber in den neuen.

Der "MusterCode" wird wohl noch anwachsen, so dass möglichst viel von dem, was ich öfter mal für ein Programm brauche, da zum Rauskopieren enthalten ist. So kann ich einfach den Programmteil, die zugehörige Deklaration, sowie die Einstellungen im Setup schnell rüber kopieren und nur noch in den Bezeichnungen teilweise anpassen.

Jetzt zum eigentlichen Problem. Wenn ich den Pin10 als PWM_PIN3 deklariere, dann bekomme ich Probleme bei der Tonausgabe auf Pin 17. Also wenn ich Pin 10 anstelle von Pin 9 als PWM Ausgang benutze, dann wird die Tonfrequenz von Pin17 liniar mit dem eingestellten PWM Signal verändert. Wenn ich wie jetzt im Programm für Pin10 den Pin9 verwende ist da kein Problem mehr. Der Pin10 ist genauso wie Pin9 nicht beschalten. Was ja bei einem OUTPUT Pin kein Problem ist.

Hier mal das Programm: Ich bin jetzt mal eine Std. unterwegs. Aber freue mich schon mal auf Infos. Ich finde keinen Zusammenhang BlushConfused

Code:
// Titel des Programmes
// AAA_A
// Das Display ist ein LCD Display mti 4 Zeilen je 20 Zeichen
// Das Potentionmeter ist ein 5-10 KiloOhm Poti mit kleiner Leistung
// Die Taster sind einfache Schließer

// Deklarationen

// Timer DS3231 einrichten
#include "Wire.h"
#define DS3231_ADDRESSE 0x68
unsigned long Sekundenablauf05 = 0; // Zeitausgabe alle 1000ms 1 Sekunde einrichten
const unsigned long Pausezeit05 = 1000;

// LCD Display einrichten
#include <LiquidCrystal_I2C.h> // LCD Display
// Displayadresse ist 0x27 oder 0x3F
LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);

// Baudrate fuer Serial Schnittstelle
const int baudSerial = 9600;

//-----------------------Taster01----------------------------------------
// const byte ist im Programm Constant und byte ist fuer Werte 0-255
// Der Taster muss einen GND haben und den auf Pin15 schalten
const byte Taster01 = 15;           // Pin 15 wird Constant als Taster01 bezeichnet
byte Tasterstatus01 = 0;            // Zum Abfragen des Tatsenpins
byte Tastenmerker01 = 0;            // Zum Merken des aktuellen Tastenstatus
unsigned long Sekundenablauf01 = 0; // Tastenabfrage von Taster01 300ms aussetzen
const unsigned long Pausezeit01 = 300;

//-----------------------Taster02---------------------------------------
// Der Taster muss einen GND haben und den auf Pin16 schalten
const byte Taster02 = 16;           // Pin16 wird Constant als Taster02 bezeichnet
byte Tasterstatus02 = 0;
byte Tastenmerker02 = 0;
unsigned long Sekundenablauf02 = 0; // Tastenabfrage von Taster02 300ms aussetzen
const unsigned long Pausezeit02 = 300;

//-----------------------Analoger Eingang A0------------------------------
// Hier wird ein 5-10 KOhm Poti an +/- angeschlossen und der Mittelabgriff auf A0
const byte ANALOG_PIN = A0; // Hier wird der Name fuer den Steuereingang festgelegt
int a0 = 0;      // Der Speicher fuer den Analogwert
int a0alt = 0;   // Der Speicher fuer den alten Analogwert
// Der Wert aus Pin A0 wird gemept als Wert 0-255 an die PWM Pin´s 9/11/13 ausgegeben
//-----------------------PWM Pins festlegen am Mega-----------------------
/* Timer und zugehörige Pinns:
   timer 0 (controls pin 13, 4);
   timer 1 (controls pin 12, 11);
   timer 2 (controls pin 10, 9);
   timer 3 (controls pin 5, 3, 2);
   timer 4 (controls pin 8, 7, 6);
*/
const int PWM_PIN2 = 13;  // PWM Ausgabepin 13 festlegen auf 490Hz, Timer0
const int PWM_PIN1 = 11;  // PWM Ausgabepin 11 festlegen auf 31300Hz, Timer1
const int PWM_PIN3 = 9;  // PWM Ausgabepin 9 festlegen auf 980Hz, Timer2

//-----------------------AusgangPIN21-------------------------------------
const byte Ausgang01 = 31;          // Pin 31 ist für das Relais01
byte Ausgangsstatus01 = 0;
unsigned long Sekundenablauf03 = 0; // Ausgang Schaltzeit auf 3000ms 3 Sekunden einrichten
const unsigned long Pausezeit03 = 3000;

//-----------------------AusgangPIN22-------------------------------------
const byte Ausgang02 = 32;          // Pin 32 ist für das Relais02
byte Ausgangsstatus02 = 0;
unsigned long Sekundenablauf04 = 0; // Ausgang Schaltzeit auf 1000ms 1 Sekunde einrichten
const unsigned long Pausezeit04 = 1000;

//-------------------------Tonausgabe PIN 17-----------------------------
const byte tonPin = 17;
const int frequenz = 440;
const int tonZeit = 100;
const int frequenz2 = 1000;

//================================================================================​=============================
void setup() {

  //I2C für DS3231 (RC Uhr) aktivieren
  Wire.begin();
  // Wenn die I2C Leitung länger ist, kann man den Tackt für den I2C Bus langsammer machen!!
  Wire.setClock(32000);

  // Serial Schnittstelle starten
  Serial.begin(baudSerial);

  // Wenn die Zeit gestellt werden muß, Auskommentierung entfernen
  // aktuelle Zeit     sek min std wt tag monat jahr
  // einstellenDS3231zeit(00, 00, 15, 3, 15,  01,  20);

  // ----------PWM Tackt für Pin 11&12 auf 31300Hz ändern---------------
  TCCR1B = TCCR1B & 0b11111000 | 0x01;

  //-----------LCD Display Start----------------------------------------
  lcd.begin(20, 4);
  lcd.backlight();
  lcd.clear();
  //-----------Taster einrichten----------------------------------------
  pinMode(Taster01, INPUT_PULLUP); // Pin 11 fuer Taster01 wird intern auf plus gelegt. Mit GND ueber Taste aktivieren
  pinMode(Taster02, INPUT_PULLUP); // Pin 12 fuer Taster02
  //-----------Ausgang einrichten---------------------------------------
  pinMode(Ausgang01, OUTPUT);      // Pin 31 (Ausgang01) ist als Ausgang aktiviert
  pinMode(Ausgang02, OUTPUT);      // Pin 32 (Ausgang02) ist als Ausgang aktiviert
  //-----------Input und Output Pin für PWM bestimmen-------------------
  pinMode(ANALOG_PIN, INPUT);      // Eingang für Poti
  pinMode(PWM_PIN1, OUTPUT);
  pinMode(PWM_PIN2, OUTPUT);
  pinMode(PWM_PIN3, OUTPUT);
  //--------------Ton Ausgabepin einrichten----------------------------
  pinMode(tonPin, OUTPUT);
}
//================================================================================​=============================
void loop() {

  //-----------Zeit ausgeben von DS3231-----------------------------------
  if (millis() - Sekundenablauf05 >= Pausezeit05) { // 300msec abgelaufen?
    zeigeZeit();                     // Jede Sekunde die Zeit ausgeben
    Sekundenablauf05 = millis();
  }
  //----------Analogen Eingang auslesen-----------------------------------
  a0 = analogRead (ANALOG_PIN);
  a0 = map(a0, 0, 1023, 25, 254);
  if ((a0 > a0alt + 2) || (a0 < a0alt - 2)) {
    //------Potiwert auf PWM Ausgang ausgeben-----------------------------
    // PWM_PIN1 Ausgabepin 13 festlegen auf 490Hz, Timer0
    // PWM_PIN2 Ausgabepin 11 festlegen auf 31300Hz, Timer1
    // PWM_PIN3 Ausgabepin 9 festlegen auf 980Hz, Timer2
    analogWrite (PWM_PIN1, a0);                       // Analogwert Ausgabe an PWM Pin.11
    analogWrite (PWM_PIN2, a0);                       // Analogwert Ausgabe an PWM Pin.13
    analogWrite (PWM_PIN3, a0);                       // Analogwert Ausgabe an PWM Pin.9
    lcd.setCursor (0, 3);
    lcd.print (F("PWM Ausgabewert "));
    lcd.setCursor (17, 3);
    lcd.print (F("   "));
    lcd.setCursor (17, 3);
    lcd.print (a0);

  }
  //-----------Taster01 abfragen--------------------------------------------
  if (millis() - Sekundenablauf01 >= Pausezeit01) { // 300msec abgelaufen?
    Tasterstatus01 = digitalRead(Taster01);         // Pin von Taster01 abfragen
    if (Tasterstatus01 == LOW) {                    // Ist Taster01 gedrueckt?
      Tastenmerker01 = !Tastenmerker01;             // Merken dass Taster01 gedrueckt wurde
      lcd.setCursor (0, 1);
      lcd.print (F("Taster  01= "));
      lcd.print (Tastenmerker01);
      Sekundenablauf01 = millis();
    }
  }

  //-----------Taster02 abfragen--------------------------------------------
  if (millis() - Sekundenablauf02 >= Pausezeit02) { // 300msec abgelaufen?
    Tasterstatus02 = digitalRead(Taster02);         // Pin von Taster02 abfragen
    if (Tasterstatus02 == LOW) {                    // Ist Taster02 gedrueckt?
      Tastenmerker02 = !Tastenmerker02;             // Merken dass Taster02 gedrueckt wurde
      lcd.setCursor (15, 1);
      lcd.print (F("02= "));
      lcd.print (Tastenmerker02);
      Sekundenablauf02 = millis();
    }
  }

  //-------------Ausgang01 schalten-------------------------------------------
  if (millis() - Sekundenablauf03 >= Pausezeit03) { // 3000msec abgelaufen?
    Ausgangsstatus01 = ! Ausgangsstatus01;          // Status wechseln
    digitalWrite (Ausgang01, Ausgangsstatus01);     // Ausgang01 Relais umschalten
    lcd.setCursor (0, 2);
    lcd.print (F("Ausgang 01= "));
    lcd.print (Ausgangsstatus01);
    Sekundenablauf03 = millis();
    tone(tonPin, frequenz2, tonZeit); // alle drei Sekunden einen 1000Hz Piep ausgeben
  }

  //-------------Ausgang02 schalten-------------------------------------------
  if (millis() - Sekundenablauf04 >= Pausezeit04) { // 1000msec abgelaufen?
    Ausgangsstatus02 = ! Ausgangsstatus02;          // Status wechseln
    digitalWrite (Ausgang02, Ausgangsstatus02);     // Ausgang01 Relais umschalten
    lcd.setCursor (15, 2);
    lcd.print (F("02= "));
    lcd.print (Ausgangsstatus02);
    Sekundenablauf04 = millis();
    tone(tonPin, frequenz, tonZeit); // Jede Sekunde einen 440Hz Piep ausgeben
  }


}
//=======================Loop Ende============================================================================​=
//---------------Erweiterung für die DS3132---------------------------------------------------------------------
void einstellenDS3231zeit(byte sekunde, byte minute, byte stunde, byte wochentag, byte tag, byte monat, byte jahr)
{
  // Datum und Uhrzeit einstellen
  Wire.beginTransmission(DS3231_ADDRESSE);
  Wire.write(0);
  Wire.write(decToBcd(sekunde)); // Sekunden einstellen
  Wire.write(decToBcd(minute)); // Minuten einstellen
  Wire.write(decToBcd(stunde));
  Wire.write(decToBcd(wochentag)); // 1=Sonntag ... 7=Samstag
  Wire.write(decToBcd(tag));
  Wire.write(decToBcd(monat));
  Wire.write(decToBcd(jahr)); // 0...99
  Wire.endTransmission();
}
//-----------------------------------------------------------------------------------------------------------
void leseDS3231zeit(byte *sekunde, byte *minute, byte *stunde, byte *wochentag, byte *tag, byte *monat, byte *jahr)
{
  Wire.beginTransmission(DS3231_ADDRESSE);
  Wire.write(0); // DS3231 Register zu 00h
  Wire.endTransmission();
  Wire.requestFrom(DS3231_ADDRESSE, 7); // 7 Byte Daten vom DS3231 holen
  *sekunde = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *stunde = bcdToDec(Wire.read() & 0x3f);
  *wochentag = bcdToDec(Wire.read());
  *tag = bcdToDec(Wire.read());
  *monat = bcdToDec(Wire.read());
  *jahr = bcdToDec(Wire.read());
}
//-----------------------------------------------------------------------------------------------------------
void zeigeZeit() {
  byte sekunde, minute, stunde, wochentag, tag, monat, jahr, minuteAlt;
  leseDS3231zeit(&sekunde, &minute, &stunde, &wochentag, &tag, &monat, &jahr);   // Daten vom DS3231 holen
  if ((minute > minuteAlt) || (minute == 0)) {
    switch (wochentag) {
      case 1:
        lcd.setCursor(0, 0);
        lcd.print(F("Mo "));
        break;
      case 2:
        lcd.setCursor(0, 0);
        lcd.print(F("Di "));
        break;
      case 3:
        lcd.setCursor(0, 0);
        lcd.print(F("Mi "));
        break;
      case 4:
        lcd.setCursor(0, 0);
        lcd.print(F("Do "));
        break;
      case 5:
        lcd.setCursor(0, 0);
        lcd.print(F("Fr "));
        break;
      case 6:
        lcd.setCursor(0, 0);
        lcd.print(F("Sa "));
        break;
      case 7:
        lcd.setCursor(0, 0);
        lcd.print(F("So "));
        break;
      default:
        break;
    }
    if (tag < 10) {
      lcd.print(F("0"));
    }
    lcd.print(tag); // ausgeben T.M.J H:M:S
    lcd.print(F("."));
    if (monat < 10) {
      lcd.print(F("0"));
    }
    lcd.print(monat);
    lcd.print(F("."));
    lcd.print(jahr);
    lcd.print(F(" um "));
    if (stunde < 10) {
      lcd.print(F("0"));
    }
    lcd.print(stunde, DEC); // byte in Dezimal zur Ausgabe
    lcd.print(F(":"));
    if (minute < 10) {
      lcd.print("0");
    }
    lcd.print(minute, DEC);
    minuteAlt = minute;
  }
}
byte decToBcd(byte val) {
  // Dezimal Zahl zu binary coded decimal (BCD) umwandeln
  return ((val / 10 * 16) + (val % 10));
}
byte bcdToDec(byte val) {
  // BCD (binary coded decimal) in Dezimal Zahl umwandeln
  return ((val / 16 * 10) + (val % 16));
}

https://www.youtube.com/watch?v=Fnzn85oWM_Q
Hier was zum Thema Deutsche Politik Angry
Und hier zum Thema richtige Politik Big Grin
Webseite des Benutzers besuchen Alle Beiträge dieses Benutzers finden
Diese Nachricht in einer Antwort zitieren
19.01.2020, 04:56 (Dieser Beitrag wurde zuletzt bearbeitet: 19.01.2020 05:31 von Franz54.)
Beitrag #2
RE: Problem am Mega mit pin 10
Ich habe natürlich vor der Änderung von pin 10 auf 9 auch schon die Änderung dess PWM Tackt´s für Pin 11&12 auf 31300Hz rausgeschmissen und alles was mit Pin 11 zu tun hatte, weil ich dachte daher kommt das Problem, dass sich die Tonfrequenz auf Pin17 mit der PWM Impulszeitänderung mitändert. Aber das brachte keine Besserung. Es brachte wirklich nur was, wenn ich den Pin 10 aus der PWM Ausgabe rausnahm und dafür Pin 9 verwendete. Aber wieso ändert sich die Tonfrequenz auf Pin 17 mit der Veränderung der PWM Ausgabe von Pin 10 Huh

Also ich verändere den Wert am Poti von Pin A0, damit ändere ich den ausgegebenen PWM Tackt auf Pin 10/11/13, was ja gewollt ist, und ändere damit aber auch die Tonfrequenz die von dem Pin 17 auf den Lautsprecher geht. Schuld an der seltsammen Verbindung ist die PWM Ausgabe auf Pin 10. Der Fehler ist weg, wenn ich für Pin 10 den Pin 9 verwende. Also das oben eingestellte Programm hat diesen Fehler nicht.
Um den Fehler wieder zu haben muss ich die Zeile:
"const int PWM_PIN3 = 9; // PWM Ausgabepin 9 festlegen auf 980Hz, Timer2"
ändern auf:
"const int PWM_PIN3 = 10; // PWM Ausgabepin 10 festlegen auf 980Hz, Timer2"

Da muss es doch irgend einen Zusammenhang geben, den ich nur nicht sehe. Confused

Grüße
Franz

https://www.youtube.com/watch?v=Fnzn85oWM_Q
Hier was zum Thema Deutsche Politik Angry
Und hier zum Thema richtige Politik Big Grin
Webseite des Benutzers besuchen Alle Beiträge dieses Benutzers finden
Diese Nachricht in einer Antwort zitieren
19.01.2020, 10:45
Beitrag #3
RE: Problem am Mega mit pin 10
Ich habe jetzt mal noch einen Fehler am Arduino ausgeschlossen, indem ich einen anderen Mega das Programm und die Anschlüße verpasst habe. Da ist genau das selbe Problem mit dem Pin 9 als dritter PWM Ausgang, ist alles Super, die Tonfrequenz lässt sich über das Poti nicht beeinflussen. Beim wechsel auf Pin10 habe ich wieder die selbe Beeinflussung des Tonausgangs abhängig von Potistellung und PWM Tackt.

Hat da echt keiner eine Idee, warum das so ist? Huh

FranzSad

https://www.youtube.com/watch?v=Fnzn85oWM_Q
Hier was zum Thema Deutsche Politik Angry
Und hier zum Thema richtige Politik Big Grin
Webseite des Benutzers besuchen Alle Beiträge dieses Benutzers finden
Diese Nachricht in einer Antwort zitieren
19.01.2020, 11:07 (Dieser Beitrag wurde zuletzt bearbeitet: 19.01.2020 11:14 von Franz54.)
Beitrag #4
RE: Problem am Mega mit pin 10
Es kann auch nicht sein, dass der Timer 2 von der Tonausgabe verändert wird, und deshalb die Tonfrequenz beeinflusst wird. Der Timer ist für Pin 9+10 verantwortlich. Somit würde es keinen Unterschied machen ob ich Pin 9 oder 10 für PMW verwende.

Es sollte doch möglich sein, eine Erklärung zu finden Huh ......hat hier keine eine Idee?? Ich dachte eigentlich, ich habe irgend eine einfache Erklärung nicht auf dem Schirm, die mir aber gleich ein paar Leute hier sagen werden Confused Dabei wird das Thema nur laufend wieder ins Abseits geschoben, dass es keiner mehr lesen kann.

Franz

https://www.youtube.com/watch?v=Fnzn85oWM_Q
Hier was zum Thema Deutsche Politik Angry
Und hier zum Thema richtige Politik Big Grin
Webseite des Benutzers besuchen Alle Beiträge dieses Benutzers finden
Diese Nachricht in einer Antwort zitieren
19.01.2020, 11:15 (Dieser Beitrag wurde zuletzt bearbeitet: 19.01.2020 11:16 von MicroBahner.)
Beitrag #5
RE: Problem am Mega mit pin 10
'Tone' und PWM (analogWrite) benutzen die HW Timer. Wenn Du da ungeschickt kombinierst, kommt sich das in die Quere. Auf dem Mega wird für den ersten 'tone' der Timer 2 benutzt. PWM an Pin 10 benutzt aber auch den Timer 2. Deshalb kommt sich das ins Gehege. Wahrscheinlich benutzen die dann auch noch das gleiche Compare-Register. Da müsste man jetzt noch genauer in den Code schauen.

Gruß, Franz-Peter
Alle Beiträge dieses Benutzers finden
Diese Nachricht in einer Antwort zitieren
19.01.2020, 11:23
Beitrag #6
RE: Problem am Mega mit pin 10
Dann muss ich mich wohl damit abfinden dass es keine eindeutige Erklärung gibt? Denn Pin 9 und Pin 10 benutzen beide den Timer 2. mit Pin 9 gibt es aber das Problem nicht Sad nur mit Pin 10.

Dann muß man wohl sagen PWM Ausgabe auf Pin 10 in verbinden mit Tonausgabe auf Pin 17 muss man meiden, weil es zusammenhänge gibt, die nicht greifbar sind. Ich habe gehoft es gäbe eine nachvollziehbare, greifbare Erklärung Confused

https://www.youtube.com/watch?v=Fnzn85oWM_Q
Hier was zum Thema Deutsche Politik Angry
Und hier zum Thema richtige Politik Big Grin
Webseite des Benutzers besuchen Alle Beiträge dieses Benutzers finden
Diese Nachricht in einer Antwort zitieren
19.01.2020, 11:25
Beitrag #7
RE: Problem am Mega mit pin 10
An der Stelle würde ich ein verlinktes Crossposting nach nebenan empfehlen.
Evtl. kennt da einer das Problem.

Gruß Tommy

"Wer den schnellen Erfolg sucht, sollte nicht programmieren, sondern Holz hacken." (Quelle unbekannt)
Alle Beiträge dieses Benutzers finden
Diese Nachricht in einer Antwort zitieren
19.01.2020, 11:44 (Dieser Beitrag wurde zuletzt bearbeitet: 19.01.2020 12:01 von MicroBahner.)
Beitrag #8
RE: Problem am Mega mit pin 10
(19.01.2020 11:23)Franz54 schrieb:  Denn Pin 9 und Pin 10 benutzen beide den Timer 2. mit Pin 9 gibt es aber das Problem nicht Sad nur mit Pin 10.
Beide nutzen aber ein unterschiedliches Compare-Register. Und der Timer 2 hat nur 2 davon - bleibt für tone keins mehr übrig Wink

Hab' mal eben in den Code geschaut: tone nutzt aktuell ausschließlich Timer 2 (auch auf dem Mega) und da den OCR2A Interrupt - also das gleiche Compare-Register, dass auch Pin10 nutzt. Das muss sich also in die Quere kommen.

Edit: nur beim 32u4 ( Micro/Leonardo) wird Timer 3 benutzt. Aber das hat ja hier keine Relevanz.

Gruß, Franz-Peter
Alle Beiträge dieses Benutzers finden
Diese Nachricht in einer Antwort zitieren
Antwort schreiben 


Möglicherweise verwandte Themen...
Thema: Verfasser Antworten: Ansichten: Letzter Beitrag
  Zeit-Server-Problem 182 21 6.426 27.08.2020 15:05
Letzter Beitrag: Bitklopfer
  Sketch von Uno auf Mega portieren Clixmaster 12 617 15.08.2020 18:36
Letzter Beitrag: hotsystems
  Timing-Problem mit zwei Nanos und I²C miq19 31 1.218 05.08.2020 15:59
Letzter Beitrag: Tommy56
Wink Arduino TFT Display MEGA 2560 Samsuino 48 14.916 23.07.2020 15:45
Letzter Beitrag: sam_217
  Neuling hat ein Problem hanebambel 1 480 01.07.2020 20:40
Letzter Beitrag: Tommy56
  Anet A8 Problem bei Firmware aufspielen evomanne 18 1.236 01.06.2020 15:49
Letzter Beitrag: Bitklopfer
  Mega 2560 R3 und Pro USB CH340G Wusl 1 393 26.05.2020 14:52
Letzter Beitrag: Tommy56
  Mega & SIM800L - Rufnummer Empfänger von String zu Char kiximek 6 718 12.05.2020 07:02
Letzter Beitrag: kiximek
  Problem mit #include GuaAck 11 1.034 03.05.2020 09:04
Letzter Beitrag: amithlon
  Problem mit Nokia 5110 Display MKnet83 17 1.562 12.04.2020 13:31
Letzter Beitrag: Tommy56

Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste